'
' Modul-Gerüst in GFA-BASIC
$m1024                                   ! GFA-Compiler-Direktive zur Steuerung
'                                        ! des Speicherbedarfs
appl_id&=APPL_INIT()                     ! Modul bei den AES anmelden
'
'                                        ! Hier Ihre Cookie-Routine eintragen!
' IF @get_cookie("XSSI",xssi_adr%)=TRUE  ! Cookie suchen und Wert merken
'  xssi_version&=WORD{xssi_adr%+4}       ! Protokoll-Version (&H101)
'   IF WORD{xssi_adr%+6}=0               ! Modul wurde nicht von BUBBLES
'     xssi_adr%=0                        ! gestartet -> XSSI-Schnittstelle
'   ENDIF                                ! wird ignoriert. Das Modul muß
' ENDIF                                  ! sein Ende nun selbst erkennen,
'                                          oder sich sofort wieder beenden!
'
white&=@alternate_white                  ! Bitte immer nur diesen VDI-
'                                          Farbindex für 'Weiß' benutzen,
'                                          um die BUBBLES-Option
'                                          'Ränder schwarz' zu unterstützen!
'
WHILE @exit=FALSE                        ! Hauptschleife
  @schonen
WEND                                     ! bis zum Ende
'
EDIT                                     ! Programm beenden
'
'
PROCEDURE schonen
  '
  ' Hier kann mit dem Bildschirm alles Mögliche angestellt werden. Sie
  ' sollten jedoch keine AES-Fenster öffnen, es sei denn, Sie melden dies
  ' mit dem Löschen von Bit 15 in vec_stat der XSSI-Struktur an.
  ' Um andere Applikationen nicht zu blockieren, sollte wind_update()
  ' vermieden werden. Sofern VDI-Ausgaben stattfinden, muß natürlich
  ' auf das korrekte Clipping geachtet werden.
  '
  PRINT "Hello BUBBLES! ";               ! der Schon-Effekt ...
  '
RETURN
'
FUNCTION exit
  $F%
  '
  ' Diese Funktion liefert TRUE, falls sich das Modul beenden soll.
  ' Die Funktion sollte möglichst oft durchlaufen werden, damit es
  ' beim Schon-Ende nicht zu unerwünschten Verzögerungen kommt.
  '
  LOCAL save_stat&,d&
  LOCAL m_state&,k_state&
  '
  ' ---- Steuerung per XSSI-Protokoll ---
  '
  IF xssi_adr%>0                         ! Ist das Protokoll installiert?
    LET save_stat&=WORD{xssi_adr%+6}     ! Schonen, solange Wert < 0 ist,
    IF save_stat&=0                      ! ansonsten Modul beenden.
      RETURN TRUE
    ELSE IF save_stat&<=-100             ! Schlüssel-Dialog ist geöffnet!
      ~GRAF_MOUSE(257,0)                 ! Mauszeiger muß sichtbar sein!
      WHILE WORD{xssi_adr%+6}<=-100      ! Keine Schon-Effekte mehr, statt-
        ~EVNT_TIMER(100)                 ! dessen Schleifchen binden, bis
      WEND                               ! Schlüssel-Dialog beendet ist.
      ~GRAF_MOUSE(256,0)                 ! Mauszeiger wieder ausschalten.
    ENDIF
    '
  ELSE
    ' -- Ende beim manuellen Modul-Start --
    '
    ~GRAF_MKSTATE(d&,d&,m_state&,k_state&) ! Maus- und Tastaturstatus holen
    IF m_state&<>0 OR k_state&<>0          ! und gegebenenfalls beenden.
      RETURN TRUE
    ENDIF
  ENDIF
  '
  ' -------- Rechenzeit abgeben ---------
  '
  ~EVNT_TIMER(100)                       ! .. bzw. Ausgaben verzögern oder das
  '                                        Tempo der Animation bestimmen.
  ' ---------- Weiter schonen -----------
  '
  RETURN FALSE
  '
ENDFUNC
'
FUNCTION alternate_white                 ! (Optional)
  $F%
  '
  ' Diese Funktion liefert gegebenenfalls einen alternativen Farbindex für
  ' die Farbe Weiß, der zur Einstellung auf der VDI-Workstation und zur
  ' Farbgebung von AES-Objekten verwendet werden sollte.
  '
  IF xssi_adr%>0                         ! Protokoll installiert?
    RETURN WORD{xssi_adr%+6}*-1-1        ! Alternativ-Weiß zurückliefern
   '                                       in GFA-BASIC eleganter:
   '                                       PRED(CARD{xssi_adr%+6})
  ELSE
    RETURN 0                             ! Standard-Farbindex für Weiß
  ENDIF
  '
ENDFUNC